{Epot_fpe.PDE  - Electric POTential & FPE  D.Bakewell 14:00 10/10/2000 }
SELECT
  regrid=on    errlim=8e-5    firstparts
COORDINATES 
  cartesian(x,y)
VARIABLES
 p     {solute probability or concentration}
DEFINITIONS
 transfer("c:\windows\desktop\PhiPLTrns.dat",Phi)
 a=0 b=10  {rect horiz and vert dimnsions, respctivly}
 d=10  d12=d/2 d15=d/5 d10=d/10 dA=0.83 d2=2*d  Vo=0.2
 xc=d/2 { x center for this boundary is +ve elctrde right edge}
 ktz=298*1.38/(6.00*pi*9.00*1.08)  { = 2.245 = KbT*(10^12)/zeta }
 Fcm=0.737 {Clusius-Msoti Fctr} k=1510*Fcm {nrmlizd valu - see Book II}
 Cdiff=ktz   {pi already defined} Vscale=Vo {scale input Phi}
 Ex=-dx(Phi)*Vscale  Ey=-dy(Phi)*Vscale     {Electric field in X, Y dirctns}
 E2=Ex*Ex+Ey*Ey  
 grdE2x=2*(Ex*dx(Ex)+Ey*dx(Ey)) {grad E^2 in X dirctn}
 grdE2y=2*(Ex*dy(Ex)+Ey*dy(Ey))  {grad E^2 in Y dirctn}
 Vx=k*grdE2x  Vy=k*grdE2y 
Areap=(2*dA)*1  pA=integral(p,2)/Areap
INITIAL VALUES
p=1/(d)*1/(b-a) 
EQUATIONS
 Cdiff*div[grad(p)]-dx[p*Vx]-dy[Vy*p]=dt(p)      { 2D FPE equation }
BOUNDARIES
Region 1   natural(p) = 0  {walking outer boundary}
 start (xc-d12,a) line to (xc+d12,a) to (xc+d12,b) to (xc-d12,b) to finish 
 {start (xc-d,a) line to (xc+d,a) to (xc+d,b) to (xc-d,b) to finish}
Region 2 start  'Aint1' (xc,a) line to (xc-dA,a) to (xc-dA,a+1)
 to (xc+dA,a+1) to (xc+dA,a) to finish 
FEATURE
start (xc-.1,a) line to (xc-.09,a) to (xc-.08,a) to (xc-.07,a) to (xc-.06,a)
 to (xc-.05,a) line to (xc-.04,a) to (xc-.03,a) to (xc-.02,a) to (xc-.01,a)
 to (xc,a) to (xc+.01,a) to (xc+.02,a) to (xc+.03,a) to (xc+.04,a) to
 (xc+.05,a) to (xc+.06,a) to (xc+.07,a) to (xc+.08,a) to (xc+.09,a) to (xc+.1,a)
TIME 0 to 50 by 0.00000001     { time range and initial timestep (secs)} 
MONITORS for cycle=10  contour(Phi) contour(p) contour(LOG10(p)) 
{elevation (p) from (xc,a) to (xc,b)  as "X-section"}
elevation (LOG10(p)) from (xc,a) to (xc,b)  as "X-section"
contour(Vx) contour(Vy)
elevation (Vx) from (xc,a) to (xc,b)  as "Vx X-section"
elevation (Vy) from (xc,a) to (xc,b)  as "Vy X-section"
HISTORIES history (p) at (xc,a)
 history (pA) report(k) report(Vo) 
END 63577